LDG-Gaming

Code: Select all

class MutPingCompensation extends Mutator;

var PlayerController LocalPlayer;

simulated function Tick(float DeltaTime)
{
  local Actor A;
  local float Ping;
  
  //only active on clients
  if ( Level.NetMode != NM_Client ) {
    Disable('Tick');
    return;
  }
  
  //return if no local controller / demo
  if ( LocalPlayer == None )
    LocalPlayer = Level.GetLocalPlayerController();
  if ( LocalPlayer == None )
    return;
  else if ( LocalPlayer.IsA('DemoRecSpectator') ) {
    Disable('Tick');
    return;
  }
  
  //this particular var is updated on call of LongClientAdjustPosition() (possibly very frequent)
  Ping = LocalPlayer.ExactPing;
  //iterate through all actors capable of movement and adjust their prepivot value (offset for where they're rendered)
  foreach DynamicActors(class'Actor', A) {
    if ( A.bProjTarget && A.Physics != PHYS_None && A.Physics != PHYS_Rotating
        && (A.Velocity != vect(0,0,0) || A.Acceleration != vect(0,0,0))
        && A.RotationRate == rot(0,0,0) && A.bCollideActors && A.Role < ROLE_Authority
        && (Projectile(A) != None && !A.IsA('FlakShell') || Pawn(A) != None && Pawn(A).Health > 0) ) {
      if ( A.bCollideWorld && (Vehicle(A) != None || A.IsA('UnrealPawn')) )
        A.PrePivot = 0.5 * (A.PrePivot + PredictLocation(A, Ping, 2) - A.Location);
      else
        A.PrePivot = 0.5 * (A.PrePivot + PredictLocation(A, Ping) - A.Location);
    }
    else if ( A.PrePivot != vect(0,0,0) )
      A.PrePivot = vect(0,0,0);
  }
}

static simulated function vector PredictLocation(Actor Other, float PredictedTime, optional int CheckWalls)
{
  local vector StartLocation, PredictedLocation, ErrorDiff;
  local vector HitLocation, HitNormal;
  
  // calculate predicted location without taking level geometry into account
  if ( Other.Physics == PHYS_Falling || Other.Physics == PHYS_Karma )
    PredictedLocation = Square(PredictedTime) * Other.PhysicsVolume.Gravity / 4
        + PredictedTime * Other.Velocity + Other.Location;
  else {
    PredictedLocation = Other.Velocity * PredictedTime + Other.Location;
    
    // adjust direction for walking players
    if ( Other.Physics == PHYS_Walking && Other.Trace(HitLocation, HitNormal,
        PredictedLocation - vect(0,0,1) * VSize(Other.Velocity), PredictedLocation, False,
        vect(0,0,1) * Other.CollisionHeight + vect(1,1,0) * Other.CollisionRadius) != None )
      PredictedLocation = HitLocation;
  }
  
  StartLocation = Other.Location;
  ErrorDiff = PredictedLocation - StartLocation;
  
  // check for walls and adjust predicted location
  while ( CheckWalls > 0 && Other.Trace(HitLocation, HitNormal, ErrorDiff + StartLocation, StartLocation,
      False, vect(0,0,1) * Other.CollisionHeight + vect(1,1,0) * Other.CollisionRadius) != None ) {
    // HitLocation is a point on the plane the player will most likely hit
    // HitNormal is that plane's normal vector
    
    ErrorDiff = PredictedLocation - HitLocation;
    if ( HitNormal.Z < -0.7 )
      PredictedLocation -= 2 * (ErrorDiff dot HitNormal) * HitNormal; // bounce off a ceiling
    else
      PredictedLocation -= (ErrorDiff dot HitNormal) * HitNormal; // project the predicted location onto the plane
    
    // If the player can land on this plane, i.e. if this is the ground, then adjust the predicted location.
    // (the player will most probably not run in the same direction after landing)
    if ( HitNormal.Z > 0.7 && Other.Physics == PHYS_Falling )
      PredictedLocation = 0.3 * PredictedLocation + 0.7 * HitLocation; // it's close enough to the real thing
        
    StartLocation = HitLocation;
    CheckWalls--;
  }
  
  return PredictedLocation;
}

Code: Select all

[PingCompensationConfig.MutPingCompensation]
bEnabled=False

Code: Select all

    else if ( A.PrePivot != vect(0,0,0) )
      A.PrePivot = vect(0,0,0);